Hitta saknade TIFF-filer
En tidigare kund behövde kontrollera att ett större bildarkiv har varje bildfil i två format, ".jpg" och ".tiff". Eftersom sökningen ska göras endast en gång så är det "Quick and dirty" som gäller, dvs. några få kodrader i AppleScript som tar fram två listor med de jpg- respektive tiff-filer som finns, och sedan helt enkelt jämför dem. Ett par minuters jobb, men flera dagars tidsvinst jämfört med att göra jobbet manuellt. Koden ser du här nedanför:
set myChosenFolder to choose folder with prompt "Välj vilken mapp du vill söka i"
set myChosenFolderPosixPath to POSIX path of (myChosenFolder as text)
set myTempPath to POSIX path of (path to temporary items)
set myAllFilePathsFile to myTempPath & "all.txt"
set myFindCMD to "find " & (quoted form of myChosenFolderPosixPath) & " -iname '*.tiff' -o -iname '*.jpg' >" & (quoted form of myAllFilePathsFile)
do shell script myFindCMD
set myJpgFiles to paragraphs of (do shell script "grep '\\.jpg$' " & myAllFilePathsFile)
set myTifFiles to paragraphs of (do shell script "grep '\\.tiff$' " & myAllFilePathsFile)
set myMissingTifFiles to {}
repeat with i from 1 to count of myJpgFiles
set myCurrentJpgfileName to item i of myJpgFiles
set myBaseName to text 1 through -4 of myCurrentJpgfileName
set myCurrentTifFileName to (myBaseName & "tiff")
if myCurrentTifFileName is not in myTifFiles then
set end of myMissingTifFiles to myCurrentTifFileName
end if
end repeat
set text item delimiters to return
display dialog "Här är de tif-filer som saknas" default answer (myMissingTifFiles as text)